Receive BLE data on ESP32

cards2019
Posts: 6
Joined: Sat Mar 06, 2021 8:14 am

Receive BLE data on ESP32

Postby cards2019 » Sat Mar 06, 2021 8:50 am

Hello, I am trying to receive data through BLE on my M5Stack Core 2, which uses an ESP32. I have an arduino that is sending a random integer between 1 and 100 and the ESP32 is reading it. I am using the BLE_client example but I cannot read the data properly. I've tried making adjustments and hacking together other examples but so far no luck. Attached is a screenshot of what the Serial Monitor looks like with the BLE_client example. Do I just need to properly convert the char from ascii to decimal? I haven't been able to get that to work yet. Does anyone have a simple example of how to receive a number value? I have done this same project with two Arduinos that worked great. One Arduino sends two characteristics - pitch and roll - and the other Arduino receives the 2 integers and plots them. I have attached my arduino code that sends data and my esp32 code that receives data. Any suggestions? Thank you.

Code: Select all

/**
 * A BLE client example that is rich in capabilities.
 * There is a lot new capabilities implemented.
 * author unknown
 * updated by chegewara
 */

#include "BLEDevice.h"
//#include "BLEScan.h"

// The remote service we wish to connect to.
static BLEUUID serviceUUID("1101");
// The characteristic of the remote service we are interested in.
static BLEUUID    charUUID("2101");

static boolean doConnect = false;
static boolean connected = false;
static boolean doScan = false;
static BLERemoteCharacteristic* pRemoteCharacteristic;
static BLEAdvertisedDevice* myDevice;

static void notifyCallback(
  BLERemoteCharacteristic* pBLERemoteCharacteristic,
  uint8_t* pData,
  size_t length,
  bool isNotify) {
    Serial.print("Notify callback for characteristic ");
    Serial.print(pBLERemoteCharacteristic->getUUID().toString().c_str());
    Serial.print(" of data length ");
    Serial.println(length);
    Serial.print("data: ");
    Serial.println((char*)pData);
}

class MyClientCallback : public BLEClientCallbacks {
  void onConnect(BLEClient* pclient) {
  }

  void onDisconnect(BLEClient* pclient) {
    connected = false;
    Serial.println("onDisconnect");
  }
};

bool connectToServer() {
    Serial.print("Forming a connection to ");
    Serial.println(myDevice->getAddress().toString().c_str());
    
    BLEClient*  pClient  = BLEDevice::createClient();
    Serial.println(" - Created client");

    pClient->setClientCallbacks(new MyClientCallback());

    // Connect to the remove BLE Server.
    pClient->connect(myDevice);  // if you pass BLEAdvertisedDevice instead of address, it will be recognized type of peer device address (public or private)
    Serial.println(" - Connected to server");

    // Obtain a reference to the service we are after in the remote BLE server.
    BLERemoteService* pRemoteService = pClient->getService(serviceUUID);
    if (pRemoteService == nullptr) {
      Serial.print("Failed to find our service UUID: ");
      Serial.println(serviceUUID.toString().c_str());
      pClient->disconnect();
      return false;
    }
    Serial.println(" - Found our service");


    // Obtain a reference to the characteristic in the service of the remote BLE server.
    pRemoteCharacteristic = pRemoteService->getCharacteristic(charUUID);
    if (pRemoteCharacteristic == nullptr) {
      Serial.print("Failed to find our characteristic UUID: ");
      Serial.println(charUUID.toString().c_str());
      pClient->disconnect();
      return false;
    }
    Serial.println(" - Found our characteristic");

    // Read the value of the characteristic.
    if(pRemoteCharacteristic->canRead()) {
      std::string value = pRemoteCharacteristic->readValue();
      Serial.print("The characteristic value was: ");
      Serial.println(value.c_str());
    }

    if(pRemoteCharacteristic->canNotify())
      pRemoteCharacteristic->registerForNotify(notifyCallback);

    connected = true;
    return true;
}
/**
 * Scan for BLE servers and find the first one that advertises the service we are looking for.
 */
class MyAdvertisedDeviceCallbacks: public BLEAdvertisedDeviceCallbacks {
 /**
   * Called for each advertising BLE server.
   */
  void onResult(BLEAdvertisedDevice advertisedDevice) {
    Serial.print("BLE Advertised Device found: ");
    Serial.println(advertisedDevice.toString().c_str());

    // We have found a device, let us now see if it contains the service we are looking for.
    if (advertisedDevice.haveServiceUUID() && advertisedDevice.isAdvertisingService(serviceUUID)) {

      BLEDevice::getScan()->stop();
      myDevice = new BLEAdvertisedDevice(advertisedDevice);
      doConnect = true;
      doScan = true;

    } // Found our server
  } // onResult
}; // MyAdvertisedDeviceCallbacks


void setup() {
  Serial.begin(115200);
  Serial.println("Starting Arduino BLE Client application...");
  BLEDevice::init("");

  // Retrieve a Scanner and set the callback we want to use to be informed when we
  // have detected a new device.  Specify that we want active scanning and start the
  // scan to run for 5 seconds.
  BLEScan* pBLEScan = BLEDevice::getScan();
  pBLEScan->setAdvertisedDeviceCallbacks(new MyAdvertisedDeviceCallbacks());
  pBLEScan->setInterval(1349);
  pBLEScan->setWindow(449);
  pBLEScan->setActiveScan(true);
  pBLEScan->start(5, false);
} // End of setup.


// This is the Arduino main loop function.
void loop() {

  // If the flag "doConnect" is true then we have scanned for and found the desired
  // BLE Server with which we wish to connect.  Now we connect to it.  Once we are 
  // connected we set the connected flag to be true.
  if (doConnect == true) {
    if (connectToServer()) {
      Serial.println("We are now connected to the BLE Server.");
    } else {
      Serial.println("We have failed to connect to the server; there is nothin more we will do.");
    }
    doConnect = false;
  }

  // If we are connected to a peer BLE Server, update the characteristic each time we are reached
  // with the current time since boot.
  if (connected) {
    String newValue = "Time since boot: " + String(millis()/1000);
    Serial.println("Setting new characteristic value to \"" + newValue + "\"");
    
    // Set the characteristic's value to be the array of bytes that is actually a string.
    pRemoteCharacteristic->writeValue(newValue.c_str(), newValue.length());
  }else if(doScan){
    BLEDevice::getScan()->start(0);  // this is just eample to start scan after disconnect, most likely there is better way to do it in arduino
  }
  
  delay(1000); // Delay a second between loops.
} // End of loop

Code: Select all

//SEND RANDOM NUMBER TO ESP32
#include <ArduinoBLE.h>
#include <Arduino_LSM6DS3.h>

BLEService IMUservice("1101");
BLEUnsignedCharCharacteristic pitchChar("2101", BLERead | BLENotify);
BLEUnsignedCharCharacteristic rollChar("3101", BLERead | BLENotify);

void setup() {
Serial.begin(9600);
pinMode(LED_BUILTIN, OUTPUT);
  
if (!BLE.begin()) 
{
while (1);
}

BLE.setLocalName("IMU");
BLE.setAdvertisedService(IMUservice);
IMUservice.addCharacteristic(pitchChar);
IMUservice.addCharacteristic(rollChar);
BLE.addService(IMUservice);

BLE.advertise();
}

void loop() 
{
BLEDevice central = BLE.central();

if (central) 
{
digitalWrite(LED_BUILTIN, HIGH);

while (central.connected()) {
//      //pitch+=1;
//      //roll-=1;
     int Pitch=random(99);
     int Roll=random(99);
      pitchChar.writeValue(Pitch);
      Serial.print(Pitch);
      rollChar.writeValue(Roll);
      Serial.print(Roll);
      delay(1);
 }
}
digitalWrite(LED_BUILTIN, LOW);
}
Attachments
ble.PNG
serial monitor
ble.PNG (155.51 KiB) Viewed 1174 times

chegewara
Posts: 1720
Joined: Wed Jun 14, 2017 9:00 pm

Re: Receive BLE data on ESP32

Postby chegewara » Sun Mar 07, 2021 11:05 am

To me all works fine, but you are trying to print char string, which should be 0x0 terminated:

Code: Select all

static void notifyCallback(
  BLERemoteCharacteristic* pBLERemoteCharacteristic,
  uint8_t* pData,
  size_t length,
  bool isNotify) {
    Serial.print("Notify callback for characteristic ");
    Serial.print(pBLERemoteCharacteristic->getUUID().toString().c_str());
    Serial.print(" of data length ");
    Serial.println(length);
    Serial.print("data: ");
    Serial.println((char*)pData);
}
What you are sending is integer value (easy way, because its 1 byte value):

Code: Select all

Serial.println(pData[0]);
or
Serial.printf("%d\n", pData[0]);

cards2019
Posts: 6
Joined: Sat Mar 06, 2021 8:14 am

Re: Receive BLE data on ESP32

Postby cards2019 » Mon Mar 08, 2021 6:17 am

Chegewara, Thank you very much! It is now working. I knew it would be something simple - I am still a beginner. Now that this is down, I can focus on how to receive the second characteristic.

Return to “ESP32 Arduino”

Who is online

Users browsing this forum: Majestic-12 [Bot] and 23 guests